# &kturtle;s &logo;-programmeringsreferens

Det här är en referens till &kturtle;s &logo;. I det här kapitlet nämner vi kort alla olika instruktionstyper. Därefter förklaras alla kommandon i tur och ordning. Härnäst följer förklaringar av behållare, matematiska beräkningar, frågor och kommandon för att styra körningen. Till sist visas hur du kan skapa dina egna kommandon med lär.

## Olika instruktionstyper

Som alla språk har Logo olika typer av ord och symboler. Här förklaras kortfattat skillnaden mellan typerna.

### Kommandon

Du talar om för sköldpaddan eller &kturtle; att göra något med kommandon. Vissa kommandon behöver indata, andra ger utdata.

    # framåt är ett kommando som behöver indata, i det här fallet talet 100:
    framåt 100

För en detaljerad översikt av alla kommandon som &kturtle; stöder, titta här.

### Tal

Troligen kan du redan en hel del om tal. Sättet som tal används i &kturtle; är inte särskilt annorlunda än ett talat språk eller matematik.

Vi har de så kallade naturliga talen: `0`, `1`, `2`, `3`, `4`, `5`, etc. De negativa talen: `-1`, `-2`, `-3`, etc. Och talen med decimaler eller kommatalen, till exempel: `0,1`, `3,14`, `33,3333`, `-5,05`, `-1,0`.

Tal kan användas i matematiska beräkningar och frågor. De kan också placeras i behållare.

Tal är färglagda med blått i kodeditorn.

### Strängar

Först ett exempel:

    skriv "Hej, jag är en sträng."

I det här exemplet är `skriv` ett kommando, medan `"Hej, jag är en sträng."` är en sträng. Strängar börjar och slutar med tecknet `"`. Det är dessa tecken som gör att &kturtle; vet att det är en sträng.

Strängar kan placeras i behållare, men de kan inte användas i matematiska beräkningar eller i frågor.

Strängar färgläggs med mörkrött i kodeditorn.

### Namn

När du använder programspråket &logo; skapar du nya saker. Om du skriver ett program behöver du ofta behållare och ibland behöver du lär för att skapa nya kommandon. När du skapar en behållare eller ett nytt kommando med lär måste du ange ett namn.

Du kan välja vilket namn som helst, under förutsättning att det inte redan har en betydelse. Du kan till exempel inte namnge en behållare framåt, eftersom det namnet redan används för ett kommando, och redan har en betydelse.

    # Här används framåt som en behållare, men det har redan en betydelse,
    # alltså orsakar det här ett fel:
    framåt = 20

    # Det här fungerar:
    framåt 20

Namn kan bara innehålla bokstäver, siffror och understreck (_), och de måste börja med en bokstav.

Läs gärna dokumentationen om behållare och kommandot lär för en bättre förklaring och fler exempel.

### Tilldelningar

Tilldelning görs med tecknet `=`. I programmeringsspråk är det bättre att inte uttala ett ensamt `=` som 'är lika med' utan som 'blir'. Uttrycket 'är lika med' är lämpligare för `==`, som är en fråga.

Tilldelningar används i allmänhet av två orsaker: (1) för att lägga till innehåll i behållare, och (2) för att ändra innehållet i en behållare. Till exempel:

    x = 10
    # Behållaren x innehåller nu talet 10.
    W = "Min ålder är: "
    # Behållaren W innehåller nu "Min ålder är: ".
    # Det här skriver ut behållarna 'W' och 'x' på duken
    skriv W + x

För fler exempel, se avsnittet om behållare.

### Matematiska symboler

&kturtle; stöder alla grundläggande matematiska symboler: addera (`+`), subtrahera (`-`), multiplicera (`*`), dividera (`/`) och parenteser `(` och `)`.

För en fullständig förklaring och fler exempel, se avsnittet om matematiska beräkningar.

### Frågor

Vi kan ställa enkla frågor där svaret är 'sant' eller 'falskt'.

Att använda frågor beskrivs utförligt i avsnittet om frågor.

### Sammanbindningsord i frågor

Frågor kan klistras ihop med så kallade 'sammanbindningsord'. Sammanbindningsorden är `och`, `eller`, och det speciella sammanbindningsordet `inte`.

Att använda sammanbindningsord i frågor förklaras i avsnittet om sammanbindningsord i frågor.

### Kommentarer

Kommentarer är rader som börjar med tecknet `#`. Till exempel:

    # Det här är en kommentar!
    skriv "Det här är inte en kommentar"
    # Föregående rad är inte en kommentar, men den nästa raden är det:
    # skriv "Det här är inte en kommentar"

Vi kan lägga till kommentarer i koden, som vi själva och andra kan läsa. Kommentarer används för att: (1) lägga till en kort beskrivning av programmet, (2) förklara hur ett kodavsnitt fungerar om det är svårt att förstå, och (3) för att 'kommentera bort' kodrader som (tillfälligt) ska ignoreras (se sista raden i exemplet).

Kommentarrader är färglagda med mörkgult i kodeditorn.

## Kommandon

Du talar om för sköldpaddan eller &kturtle; att göra något med kommandon. Vissa kommandon behöver indata, andra ger utdata. I det här avsnittet förklarar vi alla kommandon som kan användas i &kturtle;. Observera att alla inbyggda kommandon som vi beskriver här är färglagda med mörkgrönt i kodeditorn. Det hjälper dig att urskilja dem.

### Flytta sköldpaddan

Det finns flera kommandon för att flytta sköldpaddan över skärmen.

#### framåt (fr)

framåt

-     framåt X

  `framåt` flyttar sköldpaddan framåt X bildpunkter. När pennan är sänkt lämnar sköldpaddan ett spår. `framåt` kan förkortas `fr`.

#### bakåt (ba)

bakåt

-     bakåt X

  `bakåt` flyttar sköldpaddan bakåt X bildpunkter. När pennan är sänkt lämnar sköldpaddan ett spår. `bakåt` kan förkortas `ba`.

#### svängvänster (sv)

svängvänster

-     svängvänster X

  `svängvänster` talar om för sköldpaddan att svänga X grader åt vänster. `svängvänster` kan förkortas till `sv`.

#### svänghöger (sh)

svänghöger

-     svänghöger X

  `svänghöger` talar om för sköldpaddan att svänga X grader åt höger. `svänghöger` kan förkortas till `sh`.

#### riktning (ri)

riktning

-     riktning X

  `riktning` ställer in sköldpaddans riktning till X grader från noll, och är på så sätt inte relativ till sköldpaddans tidigare riktning. `riktning` kan förkortas till `ri`.

#### mitten

mitten

-     mitten

  `mitten` flyttar sköldpaddan till dukens mitt.

#### gå

gå

-     gå X,Y

  `gå` talar om för sköldpaddan att gå till en viss plats på duken. Den platsen är X bildpunkter från dukens vänsterkant och Y bildpunkter från dukens överkant. Observera att sköldpaddan inte ritar någon linje när kommandot `gå` används.

#### gåx

gåx

-     gåx X

  `gåx` gör att sköldpaddan flyttas X bildpunkter från dukens vänsterkant, medan den bibehåller samma höjd.

#### gåy

gåy

-     gåy Y

  `gåy` gör att sköldpaddan flyttas Y bildpunkter från dukens överkant, medan den behåller samma avstånd från dukens vänsterkant.

### Sköldpaddan har en penna

Sköldpaddan har en penna som ritar en linje medan sköldpaddan rör sig. Det finns några få kommandon att styra pennan. I det här avsnittet förklarar vi dessa kommandon.

#### höjpenna (hp)

höjpenna

-     höjpenna

  `höjpenna` lyfter pennan från duken. När pennan är höjd, ritas ingen linje när sköldpaddan rör sig. Se också `sänkpenna`. `höjpenna` kan förkortas till `hp`.

#### sänkpenna (sp)

sänkpenna

-     sänkpenna

  `sänkpenna` sänker ner pennan på duken. När pennan är sänkt, ritas en linje när sköldpaddan rör sig. Se också `höjpenna`. `sänkpenna` kan förkortas till `sp`.

#### pennbredd (pb)

pennbredd

-     pennbredd X

  `pennbredd` ställer in pennans bredd (linjebredden) till X bildpunkter. `pennbredd` kan förkortas till `pb`.

#### pennfärg (pf)

pennfärg

-     pennfärg R,G,B

  `pennfärg` ställer in pennans färg. `pennfärg` behöver en RGB-kombination som indata. `pennfärg` kan förkortas till `pf`.

### Kommandon för att hantera duken

Det finns flera kommandon för att hantera duken.

#### dukstorlek (ds)

dukstorlek

-     dukstorlek X,Y

  Med kommandot `dukstorlek` kan du ange dukens storlek. Det behöver X och Y som indata, där X är den nya dukbredden i bildpunkter och Y är den nya dukhöjden i bildpunkter. `dukstorlek` kan förkortas till `ds`.

#### dukfärg (df)

dukfärg

-     dukfärg R,G,B

  `dukfärg` anger dukens färg. `dukfärg` behöver en RGB-kombination som indata. `dukfärg` kan förkortas till `df`.

#### rundpå

rundpå

-     rundpå

  Med kommandot `rundpå` kan du runda duken. Se ordlistan om du vill veta vad runda betyder.

#### rundav

rundav

-     rundav

  Med kommandot `rundav` kan du göra motsatsen till att runda duken: Det betyder att sköldpaddan kan flyttas utanför duken och kan 'försvinna'. Se ordlistan om du vill veta vad runda betyder.

### Kommandon för att städa

Det finns två kommandon för att städa duken efter du har ställt till den.

#### rensa (ren)

rensa

-     rensa

  Med `rensa` suddar du allt som ritats på duken. Allt annat blir kvar: sköldpaddans position och vinkel, dukfärgen, sköldpaddans synlighet och dukstorleken. `rensa` kan förkortas `ren`.

#### återställ

återställ

-     återställ

  `återställ` städar mycket noggrannare än kommandot `rensa`. Efter kommandot `återställ` är allt som det var precis när du startat &kturtle;. Sköldpaddan är placerad i mitten av skärmen, dukfärgen är vit och sköldpaddan ritar en svart linje på duken.

### Sköldpaddan är en sprite

Först en kort förklaring av vad en sprite är: En sprite är en liten bild som kan flyttas omkring på skärmen, som vi ofta ser i datorspel. Vår sköldpadda är alltså en sprite. För ytterligare information se ordförklaringen av sprite.

Härnäst hittar du en fullständig översikt av alla kommandon som arbetar med en sprite.

(Kturtles nuvarande version stöder ännu inte användning av någon annan sprite än sköldpaddan. I framtida versioner kommer du att kunna ändra sköldpaddan till något som du själv skapat.)

#### visa

visa (vi)

-     visa

  `visa` gör sköldpaddan synlig igen efter den har gömts. `visa` kan förkortas till `vi`.

#### göm (gö)

göm

-     göm

  `göm` gömmer sköldpaddan. Det kan användas om sköldpaddan inte passar in i bilden. `göm` kan förkortas `gö`.

### Kan sköldpaddorna skriva?

Svaret är ja. Sköldpaddan kan skriva. Den skriver nästan vad som helst som du talar om för den att skriva.

#### skriv

skriv

-     skriv X

  Kommandot `skriv` används för att tala om för sköldpaddan att skriva någonting på duken. `skriv` behöver tal och strängar som indata. Du kan använda `skriv` för att skriva ut olika tal och strängar med symbolen '+'. Här är ett litet exempel:

      år = 2003
      upphovsman = "Cies"
      skriv upphovsman + " startade projektet Kturtle " + år + " och gillar ännu att jobba med det!"

#### teckenstorlek

teckenstorlek

-     teckenstorlek X

  `teckenstorlek` anger storlek på teckensnittet som används av `skriv`. `teckenstorlek` behöver indata som ska vara ett tal. Storleken ställs in i bildpunkter.

### Ett kommando som rullar tärningar åt dig

Det finns ett kommando som rullar tärningar åt dig. Det kallas `slump`, och är mycket användbart för att få oförutsedda resultat.

slump

-     slump X,Y

  `slump` är ett kommando som kräver indata och ger utdata. Två tal krävs som indata, det första (X) anger minimal utdata och det andra (Y) anger maximal. Utdata är ett slumpmässigt valt tal som är större än eller lika med minimum och mindre än eller lika med maximum. Här är ett litet exempel:

      upprepa 500 [
        x = slump 1,20
        framåt x
        svängvänster 10 - x
      ]

  Med kommandot slump kan du lägga till en viss mängd kaos i programmet.

### Inmatning och återmatning via dialogrutor

En dialogruta är ett litet fönster som dyker upp och tillhandahåller återmatning eller frågar efter inmatning. &kturtle; har två kommandon för dialogrutor, närmare bestämt `meddelande` och `indatafönster`.

#### meddelande

meddelande

-     meddelande X

  Kommandot `meddelande` har en sträng som indata. Det visar en dialogruta som innehåller texten från strängen.

      år = 2003
      upphovsman = "Cies"
      skriv upphovsman + " startade projektet Kturtle " + år + " och gillar ännu att jobba med det!"

#### indatafönster

indatafönster

-     indatafönster X

  Kommandot `indatafönster` har en sträng som indata. Det visar en dialogruta som innehåller texten från strängen, precis som meddelande, men dessutom lägger det till ett inmatningsfält i dialogrutan. Användaren kan skriva in ett tal eller en sträng via inmatningsfältet, som kan lagras i en behållare. Till exempel

      in = indatafönster "Hur gammal är du?"
      ut = 2003 - in
      skriv "År 2003 var du " + ut + " år gammal vid något tillfälle."

  Om en användare avbryter inmatningsdialogrutan, eller inte skriver in någonting alls, töms behållaren.

## Behållare

Behållare är bokstäver eller ord som kan användas av programmeraren för att lagra ett tal eller text. Behållare som innehåller ett tal kallas variabler, medan behållare som innehåller text kallas strängar.

Behållare som inte används innehåller ingenting. Ett exempel:

    skriv N

Detta skriver ingenting. Om vi försöker utföra beräkningar med tomma behållare får vi fel.

### Variabler: talbehållare

Låt oss börja med ett exempel:

    x = 3
    skriv x

På första raden görs bokstaven `x` till en variabel (talbehållare). Som du ser sätts värdet på variabeln `x` till 3. På andra raden skrivs värdet ut.

Observera att om vi ville skriva ut ett x, skulle vi ha skrivit

    skriv "x"

Det var enkelt. Nu ett lite svårare exempel:

    A = 2004
    B = 25
    C = A + B

    # nästa kommando skriver "2029"
    skriv C
    bakåt 30
    # nästa kommando skriver "2004 plus 25"
    skriv A + " plus " + B
    bakåt 30
    # nästa kommando skriver "1979"
    skriv A - B

På de första två raderna sätts variablerna `A` och `B` till 2004 och 25. På den tredje raden sätts variabeln `C` till `A + B`, vilket är 2029. Resten av exemplet består av tre kommandon `skriv` med `bakåt 30` mellan. Kommandot `bakåt 30` finns där för att vara säker på att all utskrift är på en ny rad. I exemplet ser du också att variabler kan användas i matematiska beräkningar.

### Behållare som innehåller text (strängar)

I programkod inleds och avslutas vanlig text med citationstecken. Som vi redan har sett:

    skriv "Hej, programmerare!"

Den vanliga texten avgränsas med citationstecken. Denna vanliga text kallar vi en sträng.

Strängar kan också lagras i behållare precis som tal. Strängar är mycket lika variabler. Den största skillnaden är att de innehåller text istället för tal. Av den orsaken kan inte strängar användas i matematiska beräkningar och frågor. Ett exempel på användning av strängar:

    x = "Hej "
    namn = indatafönster "Skriv in ditt namn..."
    skriv x + namn + ", hur står det till?"

På första raden sätts strängen `x` till Hej . På andra raden sätts strängen `namn` till utdata från kommandot `indatafönster`. På tredje raden skriver programmet ut en sammanslagning av de tre strängarna på duken.

Programmet ber dig skriva in ditt namn. Om du till exempel skriver in namnet Anna, skriver programmet ut Hej Anna, hur står det till?. Observera att plus (+) är den enda matematiska symbolen som du kan använda med strängar.

## Kan sköldpaddan räkna?

Ja, Kturtle räknar åt dig. Du kan addera (+), subtrahera (-), multiplicera (*) och dividera (/). Detta är ett exempel där vi använder allihop:

    a = 20 - 5
    b = 15 * 2
    c = 30 / 30
    d = 1 + 1
    skriv "a: "+a+", b: "+b+", c: "+c+", d: "+d

Vet du vilka värden som a, b, c och d har? Observera användningen av tilldelningssymbolen `=`.

Om du bara vill göra en enkel beräkning kan du skriva något som liknar detta:

    skriv 2004-12

Nu ett exempel med parenteser:

    skriv ( ( 20 - 5 ) * 2 / 30 ) + 1

Det som är mellan parenteser räknas ut först. I det här exemplet beräknas 20-5, och därefter multipliceras det med 2, divideras med 30 och därefter läggs 1 till (vilket ger 2).

## Ställa frågor, få svar ...

Kommandona `om` och `medan` styr körningen som diskuteras i nästa avsnitt. I det här avsnittet använder vi kommandot `om` för att förklara frågor.

### Frågor

Ett enkelt exempel på en fråga:

    x = 6
    om x > 5 [
      skriv "Hej"
    ]

I det här exemplet är frågan `x > 5`. Om svaret på frågan är 'sant', utförs koden mellan hakparenteserna. Frågor är en viktig del av programmering, och används ofta tillsammans med kommandon som styr körningen, som `om`. Alla tal och variabler (talbehållare) kan jämföras med varandra med frågor.

Här är alla möjliga frågor:

### Typer av frågor

`a == b` | är lika med | svaret är sant om `a` är lika med `b`
`a != b` | inte lika med | svaret är sant om `a` inte är lika med `b`
`a > b` | större än | svaret är sant om `a` är större än `b`
`a < b` | mindre än | svaret är sant om `a` är mindre än `b`
`a >= b` | större än eller lika med | svaret är sant om `a` är större än eller lika med `b`
`a <= b` | mindre än eller lika med | svaret är sant om `a` är mindre än eller lika med `b`

Frågor är färglagda med ljusblått i kodeditorn.

### Sammanbindning av frågor

Sammanbindningsord i frågor gör det möjligt att klistra ihop frågor till en stor fråga.

    a = 1
    b = 5
    om a < 5 och b == 5 [
      skriv "Hej"
    ]

I det här exemplet används sammanbindningsordet `och` för att klistra ihop två frågor (`a < 5`, `b == 5`). Om en sida av `och` skulle ge svaret falskt, skulle svaret på hela frågan vara falskt, eftersom med sammanbindningsordet `och` måste båda sidor vara sanna för att svaret ska vara sant.

Här är en grov översikt, medan en mer detaljerad förklaring följer nedan:

### Sammanbindningsord i frågor

`och` | Båda sidor måste vara 'sanna' för att svaret ska vara 'sant'
`eller` | Om en av sidorna är 'sann' är svaret 'sant'
`inte` | Specialfall: fungerar bara för en fråga. Ändrar 'sann' till 'falsk' och 'falsk' till 'sann'.

Sammanbindningsord i frågor är färglagda med violett i kodeditorn.

#### och

När två frågor sammanbinds med `och` måste båda sidorna om `och` vara 'sanna' för att resultatet ska vara 'sant'. Ett exempel:

    a = 1
    b = 5
    om ((a < 10) och (b == 5)) och (a < b) [
      skriv "Hej"
    ]

I det här exemplet ser du en sammanbunden fråga i sin tur sammanbunden med en annan fråga.

#### eller

Om en av de två frågorna som sammanbinds med `eller` är 'sann' är resultatet 'sant'. Ett exempel:

    a = 1
    b = 5
    om ((a < 10) eller (b == 10)) eller (a == 0) [
      skriv "Hej"
    ]

I det här exemplet ser du en sammanbunden fråga i sin tur sammanbunden med en annan fråga.

#### inte

`inte` är ett speciellt sammanbindningsord i frågor eftersom det bara fungerar med en fråga itaget. `inte` ändrar 'sant' till 'falskt' och 'falskt' till 'sant'. Ett exempel:

    a = 1
    b = 5
    om inte ((a < 10) och (b == 5)) [
      skriv "Hej"
    ]
    annars
    [
      skriv "Hej då"
    ]

I det här exemplet är den sammanbundna frågan 'sann', men `inte` ändrar den till 'falsk'. Alltså skrivs `"Hej då"` ut på duken.

## Styra körning

Styrning av körningen gör det möjligt för dig att styra körningen, precis som namnet anger.

Kommandon för att styra körningen färgläggs med mörkgrönt och fetstil. Hakparenteserna som oftast används tillsammans med kommandon för att styra körningen färgläggs med ljusgrönt.

### Låta sköldpaddan vänta

Om du försökt programmera en del med &kturtle; kanske du märker att sköldpaddan kan vara mycket snabb när den ritar. Det här kommandot gör att sköldpaddan väntar en angiven tid.

vänta

-     vänta X

  `vänta` låter sköldpaddan vänta X sekunder.

      upprepa 36 [
        framåt 5
        svänghöger 10
        vänta 0.5
      ]

  Den här koden ritar en cirkel, men sköldpaddan väntar en halv sekund mellan varje steg. Det ger intrycket av en sköldpadda som rör sig långsamt.

### Kör "om"

om

-     om fråga [ ... ]

  Koden som ersätter '...' utförs bara `om` svaret på frågan är 'sant'. Läs gärna om frågor i avsnittet om frågor för mer information.

      x = 6
      om x > 5 [
        skriv "x är större än fem!"
      ]

  På den första raden sätts `x` till 6. På den andra raden ställs frågan `x > 5`. Eftersom svaret på frågan är 'sant', tillåter kommandot för styrning av körningen `om` att koden mellan hakparenteserna utförs.

### En "medan" snurra

medan

-     medan fråga [ ... ]

  Kommandot för styrning av körningen `medan` liknar `om` en hel del. Skillnaden är att `medan` upprepar koden mellan hakparenteserna, ända till svaret på frågan blir 'falskt'.

      x = 1
      medan x < 5 [
        framåt 10
        vänta 1
        x = x + 1
      ]

  På den första raden sätts `x` till 1. På den andra raden ställs frågan `x < 5`. Eftersom svaret på frågan är sant utförs kommandot `medan` för styrning av körningen koden mellan hakparenteserna, ända till svaret på frågan blir falskt. I det här fallet utförs koden mellan hakparenteserna 4 gånger, eftersom varje gång den femte raden utförs blir `x` ett större.

### Om inte, med andra ord "annars"

annars

-     om fråga [...] annars [ ... ]

  `annars` kan användas som tillägg till kommandot för styrning av körningen `om`. Koden mellan hakparenteserna efter `annars` utförs bara om svaret på frågan som ställs är falskt.

      x = 4
      om x > 5 [
        skriv "x är större än fem!"
      ] annars [
        skriv "x är mindre än sex!"
      ]

  Frågan kontrollerar om `x` är större än 5. Eftersom `x` sätts till 4 på första raden är svaret på frågan falskt. Det betyder att koden mellan hakparenteserna efter `annars` utförs.

### En "för" snurra, en räknande snurra

för

-     för startpunkt till slutpunkt [ ... ]

  Snurran `för` är en 'räknande snurra'. Den håller räkning åt dig.

      för x = 1 till 10 [
        skriv x * 7
        framåt 15
      ]

  Varje gång koden mellan hakparenteserna utförs är `x` ett större, till x når värdet 10. Koden mellan hakparenteserna skriver ut `x` multiplicerat med 7. Efter programmet har kört färdigt, ser du sjuans multiplikationstabell på duken.

## Skapa dina egna kommandon med lär

`lär` är ett mycket speciellt kommando, eftersom det används för att skapa dina egna kommandon. Kommandot som du skapar kan ha indata och returnera utdata. Låt oss ta en titt på hur ett nytt kommando skapas.

    lär cirkel x [
      upprepa 36 [
        framåt x
        svängvänster 10
      ]
    ]

Det nya kommandot kallas `cirkel`. `cirkel` har indata, ett tal som anger cirkelns storlek. `cirkel` returnerar ingen utdata. Kommandot `cirkel` kan nu användas som ett vanligt kommando i resten av koden. Se följande exempel:

    lär cirkel x [
      upprepa 36 [
        framåt x
        svängvänster 10
      ]
    ]

    gå 30,30
    cirkel 20

    gå 40,40
    cirkel 50

I nästa exempel skapas ett kommando som returnerar ett värde.

    återställ

    lär multipliceraMedSigSjälv n [
      r = n * 1
      r = n * n
      returnera r
    ]
    tal = indatafönster "Ange ett tal och klicka på Ok"
    skriv tal + " multiplicerat med sig själv är: " + multipliceraMedSigSjälv tal

I det här exemplet skapas ett nytt kommando som heter `multipliceraMedSigSjälv`. Indata till kommandot multipliceras med sig själv och returneras med kommandot `returnera`. Kommandot `returnera` är sättet som används för att ge utdata från en funktion som du skapat själv.