;
; This is a script file to establish a slip
; connection with a host.
;
; Main entry point to script
;
proc main

   ; Change these variables to customize for your
   ; specific Internet service provider.

   integer nTries = 3

   ; This is the login prompt and timeout values

   string szLogin = "sername:"
   integer nLoginTimeout = 3

   ; This is the password prompt and timeout values

   string szPW = "assword:"
   integer nPWTimeout = 3

   ; This is the prompt once your password is verified

   string szPrompt = ">"

   ; This is the command to send to establish the 
   ; connection.  This script assumes you only need
   ; to issue one command to continue.  Feel free
   ; to add more commands if your provider requires
   ; it.

   string szConnect = "slip default^M"

   ; Set this to FALSE if you don't want to get an IP
   ; address

   boolean bUseSlip = TRUE


   ; Delay for 2 seconds first to make sure the
   ; host doesn't get confused when we send the
   ; two carriage-returns.

   delay 2
   transmit "^M^M"
   delay 2
   ; Attempt to login at most 'nTries' times

   while 0 < nTries do

      ; Wait for the login prompt before entering
      ; the user ID, timeout after x seconds

      waitfor szLogin then DoLogin 
        until nLoginTimeout

TryAgain:
      transmit "^M"        ; ping
      nTries = nTries - 1

   endwhile

   goto BailOut

DoLogin:
   ; Enter user ID

   transmit $USERID, raw
   transmit "^M"

   ; Wait for the password prompt 

   waitfor szPW until nPWTimeout
   if FALSE == $SUCCESS then
      goto TryAgain
   endif

   ; Send the password

   transmit $PASSWORD, raw
   transmit "^M"

   ; Wait for the prompt

   waitfor szPrompt

   transmit szConnect

   if bUseSlip then
      ; An alternative to the following 2 lines is
      ;     
      ;     set ipaddr getip 2
      ;
      ; if we don't know the order of the IP addresses.
      waitfor "our IP address is "
      set ipaddr getip
   endif

   goto Done

BailOut:
   ; Something isn't responding.  Halt the script
   ; and let the user handle it manually.

   set screen keyboard on
   halt

Done:

endproc